SQLSERVER windows 远程备份 - 重庆思庄Oracle、KingBase、PostgreSQL、Redhat认证学习论坛

7640869df665a4fbb9.png (46.63 KB, 下载次数: 0)

下载附件

2026-4-15 18:20 上传

2. 设置共享

右键文件夹 → 属性 → 共享 → 高级共享
勾选共享此文件夹，共享名例如：backup
权限 → 添加你用于访问的 Windows 账号，赋予读写 / 完全控制（一般就是administrator）

799269df666134f2d.png (84.27 KB, 下载次数: 2)

下载附件

2026-4-15 18:20 上传

关闭目标机器防火墙，或放行 445 端口（SMB 共享）

6965369df666945099.png (68.6 KB, 下载次数: 4)

下载附件

2026-4-15 18:20 上传

3. 测试访问

在sqlserver机器访问：

\\192.168.133.219\backup

能正常打开、新建文件即成功。

在cmd访问

dir \\192.168.133.219\backup

三、源机器：编写 RMAN 备份脚本（需要先下载PsExec64.exe，官网：https://learn.microsoft.com/zh-cn/sysinternals/downloads/psexec）

新建文件夹：F:\scripts

一共有以下几个文件

9892869df66745fb23.png (17.42 KB, 下载次数: 4)

下载附件

2026-4-15 18:20 上传

先弄全备

1.新建文件：F:\scripts\full_backup_remote.sql
全备
内容如下：

DECLARE @strPath NVARCHAR(200)
set @strPath = convert(NVARCHAR(19),getdate(),120)
set @strPath = REPLACE(@strPath, ':' , '-')
set @strPath = '\\192.168.133.219\backup\TEST_FULL_BACKUP_' + @strPath + '.bak'

BACKUP DATABASE [test] TO DISK = @strPath
WITH NOFORMAT, NOINIT, SKIP, REWIND, NOUNLOAD, STATS = 10
GO

2.创建批处理脚本（最终执行文件）
新建文件：F:\scripts\full_backup_remote.bat

内容如下

@echo off

:: ===================== 配置 =====================
set "REMOTE=\\192.168.133.219\backup"
set "USER=192.168.133.219\administrator"
set "PASS=oracle_4U"
set "PsExec=F:\scripts\PsExec64.exe"

:: 日志文件保存在远程，自动按日期生成
set "LOG_DATE=%date:~0,4%%date:~5,2%%date:~8,2%"
set "LOG_FILE=%REMOTE%\SQL_BACKUP_FULL_LOG_%LOG_DATE%.txt"
:: ==================================================

echo ============================================== >> "%LOG_FILE%"
echo 开始备份：%date% %time% >> "%LOG_FILE%"
echo ============================================== >> "%LOG_FILE%"

echo.
echo 日志已保存到：%LOG_FILE%
echo 开始执行备份...
echo.

:: 1. 认证共享
echo 1. 认证共享中...
%PsExec% -accepteula -s cmd /c "net use %REMOTE% %PASS% /user:%USER% /persistent:no" >> "%LOG_FILE%" 2>&1

:: 2. 删除5天前旧备份
echo 2. 删除旧备份…
%PsExec% -accepteula -s powershell -Command "Get-ChildItem -Path '%REMOTE%' -Filter 'TEST_FULL_BACKUP*.bak' -File | Where-Object { $_.LastWriteTime -lt (Get-Date).AddDays(-5) } | Remove-Item -Force" >> "%LOG_FILE%" 2>&1

:: 3. 执行SQL备份（关键：日志也输出）
echo 3. 正在备份数据库，请稍等...
%PsExec% -accepteula -s cmd /c "sqlcmd -U sa -P oracle_4U -i F:\scripts\full_backup_remote.sql" >> "%LOG_FILE%" 2>&1

:: 4. 断开连接
echo 4. 清理连接...
%PsExec% -accepteula -s cmd /c "net use %REMOTE% /delete /y" >> "%LOG_FILE%" 2>&1

echo.
echo ============================================== >> "%LOG_FILE%"
echo 备份完成：%date% %time% >> "%LOG_FILE%"
echo ============================================== >> "%LOG_FILE%"

echo 备份全部完成！日志已保存。

再弄差备

1.新建文件：F:\scripts\diff_backup_remote.sql
全备
内容如下：

DECLARE @strPath NVARCHAR(200)
set @strPath = convert(NVARCHAR(19),getdate(),120)
set @strPath = REPLACE(@strPath, ':' , '-')
set @strPath = '\\192.168.133.219\backup\TEST_DIFF_BACKUP_' + @strPath + '.bak'

BACKUP DATABASE [test] TO DISK = @strPath
WITH DIFFERENTIAL, NOFORMAT, NOINIT, SKIP, REWIND, NOUNLOAD, STATS = 10
GO

2.创建批处理脚本（最终执行文件）
新建文件：F:\scripts\diff_backup_remote.bat

内容如下

@echo off

:: ===================== 配置 =====================
set "REMOTE=\\192.168.133.219\backup"
set "USER=192.168.133.219\administrator"
set "PASS=oracle_4U"
set "PsExec=F:\scripts\PsExec64.exe"

:: 日志
set "LOG_DATE=%date:~0,4%%date:~5,2%%date:~8,2%"
set "LOG_FILE=%REMOTE%\SQL_BACKUP_DIFF_LOG_%LOG_DATE%.txt"
:: ==================================================

echo ============================================== >> "%LOG_FILE%"
echo 差异备份开始：%date% %time% >> "%LOG_FILE%"
echo ============================================== >> "%LOG_FILE%"

:: 1. 认证共享
echo 1. 认证共享中...
%PsExec% -accepteula -s cmd /c "net use %REMOTE% %PASS% /user:%USER% /persistent:no" >> "%LOG_FILE%" 2>&1

:: 2. 删除5天前的差异备份
echo 2. 删除旧备份…
%PsExec% -accepteula -s powershell -Command "Get-ChildItem -Path '%REMOTE%' -Filter 'TEST_DIFF_BACKUP*.bak' -File | Where-Object { $_.LastWriteTime -lt (Get-Date).AddDays(-5) } | Remove-Item -Force" >> "%LOG_FILE%" 2>&1

:: 3. 执行差异备份
echo 3. 正在备份数据库，请稍等...
%PsExec% -accepteula -s cmd /c "sqlcmd -U sa -P oracle_4U -i F:\scripts\diff_backup_remote.sql" >> "%LOG_FILE%" 2>&1

:: 4. 断开共享
echo 4. 清理连接...
%PsExec% -accepteula -s cmd /c "net use %REMOTE% /delete /y" >> "%LOG_FILE%" 2>&1

echo ============================================== >> "%LOG_FILE%"
echo 差异备份完成：%date% %time% >> "%LOG_FILE%"
echo ============================================== >> "%LOG_FILE%"

echo 差异备份完成，日志已保存